1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
|
z_inccycles_io:
cmp %edi, %ebp
jnb do_limit
no_sync_io:
add $4, %ebp
ret
do_limit_io:
cmp 112(%rsi), %ebp
jb no_sync_io
jmp sync_io
z_inccycles:
cmp %edi, %ebp
jnb do_limit
no_sync:
add $3, %ebp
ret
do_limit:
cmp 112(%rsi), %ebp
jb no_sync
sync_io:
call z80_save_context_scratch
pop %rax /*return address in read/write func*/
pop 104(%rsi) /*return address in native code*/
sub $5, %rax /* adjust return addres to point to the call instruction that got us here */
mov %rax, (%rsi)
pop %r15 /* restore callee saved regsiters */
pop %r14
pop %r13
pop %r12
pop %rbp
pop %rbx
ret /* return to caller of z80_run */
.global z80_handle_cycle_limit_int
z80_handle_cycle_limit_int:
cmp 116(%rsi), %ebp
jb zskip_int
mov 112(%rsi), %ebp /* set cycle limit to sync cycle */
add $7, %ebp
sub $2, %r9w
mov %r9w, %r14w
call z_inccycles
push %r13
call z80_write_byte_noinc
pop %r13
mov %r9w, %r14w
add $1, %r14w
shr $8, %r13w
call z_inccycles
call z80_write_byte_noinc
pop %r14 /*dispose of return address */
/* TODO: Support interrupt mode 0 and 2 */
mov $0x38, %r13w
call z80_native_addr
jmp *%r13
zskip_int:
cmp 112(%rsi), %ebp
jb zskip_sync
.global z80_do_sync
z80_do_sync:
call z80_save_context
pop (%rsi) /*return address in native code*/
pop %r15 /* restore callee saved regsiters */
pop %r14
pop %r13
pop %r12
pop %rbp
pop %rbx
zskip_sync:
ret
.global z80_read_byte
z80_read_byte:
call z_inccycles
z80_read_byte_noinc:
cmp $0x4000, %r13w
jb z80_read_ram
cmp $0x8000, %r13w
jae z80_read_bank
/* TODO: Bank reg, YM-2612, PSG/VDP */
mov $0xFF, %r13b
ret
z80_read_ram:
and $0x1FFF, %r13
mov (%r11, %r13), %r13b
ret
z80_read_bank:
and $0x7FFF, %r13
cmp $0, %r12
je slow_bank_read
/* 68K memory is byte swapped */
xor $1, %r13
mov (%r12, %r13), %r13b
ret
slow_bank_read:
/* TODO: Call into C to implement this */
ret
.global z80_write_byte
z80_write_byte:
call z_inccycles
z80_write_byte_noinc:
cmp $0x4000, %r14w
jb z80_write_ram
cmp $0x8000, %r14w
jae z80_write_bank
cmp $0x6000, %r14w
je z80_write_bank_reg
/* TODO: YM-2612, PSG/VDP */
ret
z80_write_ram:
and $0x1FFF, %r14
mov %r13b, (%r11, %r14)
mov %r14d, %r13d
shr $7, %r13d
bt %r13d, 152(%rsi)
jnc not_code
call z80_save_context
mov %r14d, %edi
call z80_handle_code_write
mov %rax, %rsi
call z80_load_context
not_code:
ret
z80_write_bank:
and $0x7FFF, %r14
cmp $0, %r12
je slow_bank_write
/* 68K memory is byte swapped */
xor $1, %r14
mov %r13b, (%r12, %r14)
ret
slow_bank_write:
/* TODO: Call into C to implement this */
ret
z80_write_bank_reg:
and $1, %r13w
shr %r15w
shl $8, %r13w
xor %r12, %r12
or %r13w, %r15w
and $0x1FF, %r15w
cmp $0x80, %r15w
jb update_bank_ptr
ret
update_bank_ptr:
mov %r15w, %r12w
shl $15, %r12
add 80(%rsi), %r12
ret
.global z80_read_word
z80_read_word:
call z_inccycles
push %r13
call z80_read_byte_noinc
mov %r13b, %r14b
pop %r13
inc %r13
call z_inccycles
call z80_read_byte_noinc
shl $8, %r13w
mov %r14b, %r13b
ret
.global z80_write_word_highfirst
z80_write_word_highfirst:
call z_inccycles
push %r14
push %r13
add $1, %r14w
shr $8, %r13w
call z80_write_byte_noinc
pop %r13
pop %r14
call z_inccycles
call z80_write_byte_noinc
ret
.global z80_write_word_lowfirst
z80_write_word_lowfirst:
call z_inccycles
push %r14
push %r13
call z80_write_byte_noinc
pop %r13
pop %r14
add $1, %r14w
shr $8, %r13w
call z_inccycles
call z80_write_byte_noinc
ret
.global z80_io_read
z80_io_read:
call z_inccycles_io
/* genesis Z80 has no IO port hardware and always returns FF */
mov $0xFF, %r13
ret
.global z80_io_write
z80_io_write:
call z_inccycles_io
/* genesis Z80 has no IO port hardware and writes have no effect */
ret
.global z80_retrans_stub
z80_retrans_stub:
call z80_save_context
mov %r13d, %edi
push %rsi
call z80_retranslate_inst
pop %rsi
mov %rax, %r13
call z80_load_context
jmp *%r13
.global z80_native_addr
z80_native_addr:
call z80_save_context
push %rsi
mov %rsi, %rdi
movzx %r13w, %esi
call z80_get_native_address_trans
mov %rax, %r13
pop %rsi
call z80_load_context
ret
z80_save_context_scratch:
mov %r13w, 98(%rsi) /* scratch1 */
mov %r14w, 100(%rsi) /* scratch2 */
.global z80_save_context
z80_save_context:
mov %r9w, 8(%rsi) /* SP */
mov %r15w, 16(%rsi) /* bank register */
mov %bx, 18(%rsi) /* BC */
mov %cx, 20(%rsi) /* DE */
mov %ax, 22(%rsi) /* HL */
mov %dx, 24(%rsi) /* IX */
mov %r8w, 26(%rsi) /* IY */
mov %r10b, 30(%rsi) /* A */
mov %edi, 48(%rsi) /* target_cycle */
mov %ebp, 52(%rsi) /* current_cycle */
mov %r12, 72(%rsi) /* cartridge bank pointer */
ret
z80_load_context_scratch:
mov 98(%rsi), %r13w /* scratch1 */
mov 100(%rsi), %r14w /* scratch2 */
.global z80_load_context
z80_load_context:
mov 8(%rsi), %r9w /* SP */
mov 16(%rsi), %r15w /* bank register */
mov 18(%rsi), %bx /* BC */
mov 20(%rsi), %cx /* DE */
mov 22(%rsi), %ax /* HL */
mov 24(%rsi), %dx /* IX */
mov 26(%rsi), %r8w /* IY */
mov 30(%rsi), %r10b /* A */
mov 48(%rsi), %edi /* target_cycle */
mov 52(%rsi), %ebp /* current_cycle */
mov 64(%rsi), %r11 /* z80 RAM */
mov 72(%rsi), %r12 /* cartridge bank pointer */
ret
.global z80_run
z80_run:
push %rbx
push %rbp
push %r12
push %r13
push %r14
push %r15
mov %rdi, %rsi
call z80_load_context_scratch
cmpq $0, 104(%rsi)
je no_extra
push 104(%rsi)
movq $0, 104(%rsi)
no_extra:
jmp *(%rsi)
|
